プログラムを書こう!

実務や自作アプリ開発で習得した役に立つソフトウェア技術情報を発信するブログ

VB6でイベントを使用する。

この記事は2018年12月07日に投稿しました。

目次

  1. はじめに
  2. VB6でイベントを使用する
  3. おわりに

かんたんプログラミングVisual Basic6 基礎編

かんたんプログラミングVisual Basic6 基礎編

1. はじめに

こんにちは、iOSのエディタアプリPWEditorの開発者の二俣です。
今回は業務で使用しているVB6でイベントを使用する方法についてです。

目次へ

2. VB6でイベントを使用する

VB6でイベントを使用する方法ですが、VB6でイベントは用意されていません。
そのためWin32APIのイベント関連の関数を使用します。

実装例

' APIの宣言
' イベントを生成します。
Private Declare Function CreateEvent _
           Lib "kernel32" _
           Alias "CreateEventA" ( _
           ByVal lpEventAttributes As Long, _
           ByVal bManualReset As Long, _
           ByVal bInitialState As Long, _
           ByVal lpName As Long _
           ) As Long

' イベントをシグナル状態にします。
Private Declare Function SetEvent _
           Lib "kernel32" _
           (ByVal hEvent As Long) As Long

' イベントをリセットします。
Private Declare Function ResetEvent_
           Lib "kernel32" _
           (ByVal hEvent As Long) As Long

' イベントハンドラをクローズします。
Private Declare Function CloseHandle _
           Lib "kernel32" _
           (ByVal hObject As Long) As Long

' メッセージ待ちまたはイベント待ちを行います。
Private Declare Function MsgWaitForMultipleObjects _
           Lib "user32" ( _
           ByVal nCount As Long, _          ' オブジェクトハンドルの配列に入っているハンドルの数
           pHandles As Long, _              ' オブジェクトハンドルの配列へのポインタ
           ByVal fWaitAll As Long, _        ' すべてを待機するか、いずれか1つを待機するか
           ByVal dwMilliseconds As Long, _  ' タイムアウト時間(ms)
           ByVal dwWakeMask As Long _       ' 待機するイベントの種類
           ) As Long

' メッセージ待ちするメッセージ
Private Const QS_KEY            As Long = &H1
Private Const QS_MOUSEMOVE      As Long = &H2
Private Const QS_MOUSEBUTTON    As Long = &H4
Private Const QS_POSTMESSAGE    As Long = &H8
Private Const QS_TIMER          As Long = &H10
Private Const QS_PAINT          As Long = &H20
Private Const QS_SENDMESSAGE    As Long = &H40
Private Const QS_HOTKEY         As Long = &H80
Private Const QS_MOUSE          As Long = QS_MOUSEMOVE Or QS_MOUSEBUTTON
Private Const QS_INPUT          As Long = QS_MOUSE Or QS_KEY
Private Const QS_ALLINPUT       As Long = QS_SENDMESSAGE Or QS_PAINT _
                                       Or QS_TIMER Or QS_POSTMESSAGE _
                                       Or QS_MOUSEBUTTON Or QS_MOUSEMOVE _
                                       Or QS_HOTKEY Or QS_KEY

' MsgWaitForMultipleObjectsの戻り値
Private Const WAIT_OBJECT_0     As Long = 0           ' イベントがシグナル状態になった。
Private Const WAIT_FAILED       As Long = &HFFFFFFFF  ' 関数がエラーになった。

' 無限待ち
Private Const INFINITE          As Long = &HFFFFFFFF

' イベントハンドル
Dim mhEvent As Long

' フォームがロードされた時に呼び出されます。
Private Sub Form_Load()
   ' イベントを生成します。
   mhEvent = CreateEvent(0, 0, 0, 0)
End Sub

' フォームがアンロードされた時に呼び出されます。
Private Sub Form_Unload(Cancel As Integer)
   ' イベントハンドルをクローズします。
   CloseHandle(mhEvent)
End Sub

' イベント待ちにします。
Private Sub Command1_Click()
   Dim nRet As Long

   ' イベントをリセットします。
   ResetEvent mhEvent

   ' メッセージかイベントがシグナル状態になるまでループします。
   Do
       ' メッセージとイベントを無限待ちします。
       ' メッセージは上記で定義したすべてのメッセージ(QS_XXX)を待ちます。
       nRet = MsgWaitForMultipleObjects( _
                   1, _
                   mhEvent, _
                   0, _
                   INFINITE, _
                   QS_ALLINPUT)

       ' メッセージまたはイベントが発生した場合の処理を行います。
       Select Case nRet
           ' 関数が失敗した場合(フォームが閉じられた場合など)
           Case WAIT_FAILED
               MsgBox "WAIT_FAILED"
               Exit Sub

           ' 対象のイベントがシグナル状態になった場合
           Case WAIT_OBJECT_0
               ' ループを終了して、イベント待ちを解除します。
               Exit Do

           ' 上記以外のメッセージの場合
           Case Else
               ' 一旦OSに制御を戻します。
               DoEvents
       End Select
   Loop

   ' イベント待ち後の処理を行います。

End Sub

' イベントをシグナル状態にします。
Private Sub Command2_Click()
   SetEvent mhEvent
End Sub

目次へ

3. おわりに

業務で起動画面をモードレスで起動し、かつ画面が閉じた後に後処理を行う必要があり、イベント待ちすることにしました。
WaitForSingleObject関数は知っていましたが、MsgWaitForMultipleObjects関数は初めて知りました。
まさに今回の要件にぴったりの機能でした。

プログラミングスクール【Tech Boost】

かんたんプログラミング Visual Basic 6 応用編

かんたんプログラミング Visual Basic 6 応用編

紹介している一部の記事のコードはGitlabで公開しています。
興味のある方は覗いてみてください。

目次へ


私が勤務しているニューラルでは、主に組み込み系ソフトの開発を行っております。
弊社製品のハイブリッドOS Bi-OSは高い技術力を評価されており、特に制御系や通信系を得意としています。
私自身はiOSモバイルアプリウィンドウズアプリを得意としております。
ソフトウェア開発に関して相談などございましたら、お気軽にご連絡ください。

また一緒に働きたい技術者の方も随時募集中です。
興味がありましたらご連絡ください。

EMAIL : info-nr@newral.co.jp / m-futamata@newral.co.jp
TEL : 042-523-3663
FAX : 042-540-1688

目次へ